Godotでのダイアログシステムの作成チュートリアル

extends Panel

# ダイアログウィンドウのUI要素を取得
@onready var character_name = $VBoxContainer/Name  # キャラクター名表示用
@onready var content = $VBoxContainer/Content  # ダイアログ本文表示用
@onready var next = $Next  # テキスト表示が終了合図
@onready var text_delay = $TextDelay  # テキストの表示遅延タイマー

# ダイアログ管理用変数
var is_dialog_mode = false  # ダイアログモードが有効かどうか
var text_to_display = []  # 表示するテキストのリスト
var current_index = 0  # 現在のテキストインデックス
var current_text_index = 0  # 現在の文字インデックス
var first_time = true  # 初回表示フラグ

# テキストの表示遅延処理
func _on_text_delay_timeout() -> void:
	if current_index < text_to_display.size():  # まだ表示するテキストがある場合
		if current_text_index < text_to_display[current_index].length():  # テキストを一文字ずつ表示
			content.text = text_to_display[current_index].substr(0, current_text_index + 1)
			current_text_index += 1
		else:
			text_delay.stop()  # テキスト表示完了後、タイマーを停止
			next.visible = true  # テキスト終了合図を表示
	else:
		text_delay.stop()  # すべてのテキストが表示されたら、ダイアログを閉じる
		hide()
		is_dialog_mode = false

# ユーザー入力処理
func _input(event: InputEvent) -> void:
	if event.is_action_pressed("talk"):  # 「talk」アクションが押されたとき
		if current_index < text_to_display.size():  # まだ表示するテキストがある場合
			if current_text_index == text_to_display[current_index].length() || current_text_index == 0:
				# 次のテキストを表示するための準備
				text_delay.start()
				current_text_index = 0
				current_index += 1
				next.visible = false  # テキスト終了合図を隠す
			else:
				# 現在のテキストを即座に全表示
				content.text = text_to_display[current_index]
				current_text_index = 0
				text_delay.stop()
				next.visible = true

# ダイアログを開始する関数
func start_dialog():
	content.text = ""  # テキストをクリア
	current_text_index = 0
	current_index = 0
	show()  # ダイアログウィンドウを表示
	text_delay.start()  # テキスト表示タイマーを開始
	is_dialog_mode = true

func _on_npc_interacted():
    var dialog_panel = get_node("/root/Main/Dialog")  # ダイアログパネルの取得
    dialog_panel.text_to_display = [
        "こんにちは！",
        "この村へようこそ。",
        "何かお困りですか？"
    ]
    dialog_panel.start_dialog()