2Dトップダウン脱出ゲームチュートリアル Part 4: インベントリーシステムの実装

# インベントリ内のアイテムを表すリソースクラス
class_name InventoryItem
extends Resource

## アイテムの一意な識別子（ID）
@export var item_id: int 
## アイテムの名称
@export var item_name: String 
## アイテムのアイコン画像（圧縮テクスチャ）
@export var item_icon: CompressedTexture2D 
## アイテムの説明文（複数行対応）
@export_multiline var item_description: String 

Inventory (Panel)
├── ItemImage (TextureRect)
├── InventoryLabel (Label)
├── ItemList (VBoxContainer)
├── ItemName (Label)
├── ItemDescription (Label)
└── CloseBtn (Button)

extends Panel

# インベントリのUIを管理するクラス

## アイテムのボタンブロックとして使用するシーン（インスタンス化される）
@export var item_block: PackedScene

@export_category("Item List")
## インベントリ内に初期登録されるアイテムリスト
@export var item_list: Array[InventoryItem]

# UI要素への参照（onreadyで取得）
@onready var item_list_ui = $ItemList # アイテム一覧を表示するコンテナ
@onready var item_image = $ItemImage # 選択したアイテムの画像表示
@onready var item_name = $ItemName # 選択したアイテムの名前表示
@onready var item_description = $ItemDescription # 選択したアイテムの説明表示

# インベントリ内のアイテムデータを管理するリスト
var intentory: Array[InventoryItem] = []

# 現在選択されているアイテムのインデックス（未選択時は -1）
var selected_item = -1

func _ready():
	# 初期状態ではアイテムの名前と説明を空にする
	item_name.text = ""
	item_description.text = ""

# アイテムをインベントリに追加する処理
func add_item(item):
	var new_item = item_block.instantiate() # アイテムボタンのインスタンスを作成
	new_item.get_child(0).texture_normal = item.item_icon # アイテムのアイコンを設定
	new_item.get_child(0).pressed.connect(_button_pressed.bind(intentory.size())) # ボタンが押されたときの処理を接続
	intentory.append(item) # インベントリにアイテムを追加
	item_list_ui.add_child(new_item) # UIに追加

# 指定したIDのアイテムを所持しているか判定する
func has_item(item_id):
	var found = false
	for item in intentory:
		if item.item_id == item_id:
			found = true
			break
	return found

# アイテムボタンが押されたときの処理
func _button_pressed(pos):
	if selected_item == pos:
		# すでに選択されているアイテムをクリックした場合、選択解除
		selected_item = -1
		item_image.texture = null
		item_name.text = ""
		item_description.text = ""
	else:
		# 新たにアイテムを選択
		selected_item = pos
		item_image.texture = intentory[pos].item_icon
		item_name.text = intentory[pos].item_name
		item_description.text = intentory[pos].item_description

# インベントリを閉じる
func close_inventory():
	hide()
	
# インベントリを開く
func open_inventory():
	show()