2Dトップダウン脱出ゲームチュートリアル Part 2: プレイヤーキャラクターの移動と操作の実装

extends CharacterBody2D

@export var speed = 50.0

@onready var animation = $AnimatedSprite2D  # アニメーション用ノード
@onready var detection_area = $DetectionArea  # プレイヤーの前方にある検知エリア

var dir = "down"  # プレイヤーの向き（初期は下）
var is_moving = false  # 移動中かどうかのフラグ
var object_interactable: Interactable  # 触れられるオブジェクトの参照
var can_move = true  # プレイヤーが移動可能かどうかのフラグ

# 毎フレームの物理処理
func _physics_process(delta):
	# 移動不可状態
	if !can_move:
		is_moving = false
		animate()
		return
	
	# 移動処理
	if Input.is_action_pressed("left"):
		velocity = Vector2.LEFT * speed
		detection_area.rotation_degrees = 90  # 左向き
		is_moving = true
		dir = "left"
	elif Input.is_action_pressed("right"):
		velocity = Vector2.RIGHT * speed
		is_moving = true
		detection_area.rotation_degrees = 270  # 右向き
		dir = "right"
	elif Input.is_action_pressed("up"):
		velocity = Vector2.UP * speed
		is_moving = true
		detection_area.rotation_degrees = 180  # 上向き
		dir = "up"
	elif Input.is_action_pressed("down"):
		velocity = Vector2.DOWN * speed
		is_moving = true
		detection_area.rotation_degrees = 0  # 下向き
		dir = "down"
	else:
		velocity = Vector2.ZERO
		is_moving = false

	move_and_slide()
	animate()

# アニメーション制御
func animate():
	if is_moving:
		animation.play(dir)  # 移動中のアニメーション
	else:
		animation.play("idle_" + dir)  # 静止中のアニメーション

# 検知エリアにオブジェクトが入った際の処理
func _on_detection_area_body_entered(body):
	if body is Interactable:
		object_interactable = body

# 検知エリアからオブジェクトが出た際の処理
func _on_detection_area_body_exited(body):
	object_interactable = null

# アイテムを取得する処理
func pickup():
	if object_interactable.is_pickable:
		object_interactable.queue_free()
		object_interactable = null
		
# プレイヤーの移動を停止する
func player_move_stop():
	can_move = false

# プレイヤーの移動を再開する
func player_move_start():
	can_move = true